STM8單片機中的外設資源是比較豐富的，定時器有8位的也有16位的，下面的實驗程序，就是利用8位定時器4來進行延時，然后驅動LED閃爍。

同樣還是利用ST的開發工具，生成一個匯編程序的框架，然后修改其中的main.asm，修改后的代碼如下。

編譯通過后，下載到開發板，運行程序，可以看到LED在閃爍，或者用示波器可以在LED引腳上看到方波。

在這里要特別提醒的是，從ST給的手冊上看，這個定時器中的計數器是一個加1計數器，但本人在實驗過程中感覺不太對，經過反復的實驗，我認為應該是一個減1計數器（也許是我拿的手冊不對，或許是理解上有誤）。例如，當給定時器中的自動裝載寄存器裝入255時，產生的方波頻率最小，就象下面代碼中計算的那樣，產生的方波頻率為30HZ左右。若初始化時給自動裝載寄存器裝入1，則產生的方波頻率最大，大約為3.9K左右。也就是說實際的分頻數為ARR寄存器的值+1。

stm8/

      #include "mapping.inc"

;     #include "STM8S207S8.INC"

; 涉及到的硬件資源

; 下面定義端口D的寄存器地址

PD_ODR   EQU   $500f              

PD_IDR   EQU   $5010

PD_DDR   EQU   $5011

PD_CR1   EQU   $5012

PD_CR2   EQU   $5013

; 定時器4的寄存器定義

TIM4_CR1  EQU   $5340

TIM4_IER  EQU   $5341

TIM4_SR   EQU    $5342

TIM4_EGR  EQU   $5343

TIM4_CNTR  EQU   $5344

TIM4_PSCR  EQU   $5345

TIM4_ARR  EQU   $5346

; 定義堆棧空間的起始位置和結束位置

stack_start.w  EQU   $stack_segment_start

stack_end.w   EQU    $stack_segment_end

             segment 'rom'         ; 下面開始定義一個段，該段位于ROM中

main.l                        ; 定義復位后的第一條指令的標號（即入口地址）

;

; 首先要初始化堆棧指針

             LDW    X,#stack_end       

             LDW    SP,X

; 下面初始化IO端口

; PD3設置成推挽輸出

; PD7設置成懸浮輸入

         LD     A,#08

        LD     PD_DDR,A    ; 將PD3設置成輸出，PD7設置成輸入

         LD     A,#08

           LD     PD_CR1,A     ; 將PD3設置成推挽輸出

         LD     A,#00

              LD     PD_CR2,A            ;

;

; 下面初始化定時器4                       

         LD     A,#$00

         LD     TIM4_IER,A      ; 禁止中斷

         LD     A,#$01    

         LD     TIM4_EGR,A      ; 允許產生更新事件

              LD     A,#$07

              LD     TIM4_PSCR,A      ; 計數器時鐘=主時鐘/128=2MHZ/128

                                             ; 相當于計數器周期為64uS

              LD     A,#255

              LD     TIM4_ARR,A       ; 設定重裝載時的寄存器值，255是最大值

              LD     A,#255

              LD     TIM4_CNTR,A      ; 設定計數器的初值

                                              ; 定時周期=(ARR+1)*64=16384uS

                                 ; 產生方波頻率=30.5HZ

                                                                                                                     ;

LD     A,#$01

                                     ; b0 = 1,允許計數器工作

; b1 = 0,允許更新

LD     TIM4_CR1,A      ; 設置控制器，啟動定時器

MAIN_LOOP.L

            LD     A,TIM4_SR         ; 讀入定時器4的狀態

            AND    A,#01             ; 判斷是否產生更新標志

            JREQ   MAIN_LOOP        ; 若沒有，則等待

       LD     A,#0               ; 清除更新標志

       LD     TIM4_SR,A                          

      LD     A,PD_ODR            ; 將LED驅動信號取反

      XOR    A,#$08

      LD     PD_ODR,A            ; LED閃爍頻率=2MHZ/128/255/2=30.63

    JRA    MAIN_LOOP           ; 無限循環

  interrupt NonHandledInterrupt

NonHandledInterrupt.l

      iret

; 下面定義中斷向量表    

             segment 'vectit'

             dc.l {$82000000+main}                                                     ; reset

             dc.l {$82000000+NonHandledInterrupt}   ; trap

             dc.l {$82000000+NonHandledInterrupt}   ; irq0

             dc.l {$82000000+NonHandledInterrupt}   ; irq1

             dc.l {$82000000+NonHandledInterrupt}   ; irq2

             dc.l {$82000000+NonHandledInterrupt}   ; irq3

             dc.l {$82000000+NonHandledInterrupt}   ; irq4

                  dc.l {$82000000+NonHandledInterrupt}   ; irq5

             dc.l {$82000000+NonHandledInterrupt}   ; irq6

             dc.l {$82000000+NonHandledInterrupt}   ; irq7

             dc.l {$82000000+NonHandledInterrupt}   ; irq8